base shader

frontend/src/assets/shader.glsl

@@ -0,0 +1,83 @@
+#version 300 es
+precision lowp float;
+uniform vec3 iResolution;           // viewport resolution (in pixels)
+uniform float iTime;                 // shader playback time (in seconds)
+uniform sampler2D iChannel1;
+
+out vec4 FragColor;
+
+const float pi = 3.1415927f;
+
+float sdSphere(vec3 p, float s) {
+  return length(p) - s;
+}
+
+float sdTorus(vec3 p, vec2 t) {
+  vec2 q = vec2(length(p.xz) - t.x, p.y);
+  return length(q) - t.y;
+}
+
+void mainImage(out vec4 fragColor, in vec2 fragCoord) {
+  vec2 pp = fragCoord.xy / iResolution.xy;
+  pp = -1.0f + 2.0f * pp;
+  pp.x *= iResolution.x / iResolution.y;
+
+  vec3 lookAt = vec3(0.0f, -0.1f, 0.0f);
+
+  float eyer = 2.0f;
+  float eyea = 0.0f;
+  float eyea2 = (-0.24f) * pi * 2.0f;
+
+  vec3 ro = vec3(eyer * cos(eyea) * sin(eyea2), eyer * cos(eyea2), eyer * sin(eyea) * sin(eyea2)); //camera position
+
+  vec3 front = normalize(lookAt - ro);
+  vec3 left = normalize(cross(normalize(vec3(0.0f, 1, -0.1f)), front));
+  vec3 up = normalize(cross(front, left));
+  vec3 rd = normalize(front * 1.5f + left * pp.x + up * pp.y); // rect vector
+
+  vec3 bh = vec3(0.0f, 0.0f, 0.0f);
+  float bhr = 0.1f;
+  float bhmass = 5.0f;
+  bhmass *= 0.001f; // premul G
+
+  vec3 p = ro;
+  vec3 pv = rd;
+  float dt = 0.02f;
+
+  vec3 col = vec3(0.0f);
+
+  float noncaptured = 1.0f;
+
+  vec3 c1 = vec3(0.5f, 0.46f, 0.4f);
+  vec3 c2 = vec3(1.0f, 0.8f, 0.6f);
+
+  for(float t = 0.0f; t < 1.0f; t += 0.005f) {
+    p += pv * dt * noncaptured;
+
+        // gravity
+    vec3 bhv = bh - p;
+    float r = dot(bhv, bhv);
+    pv += normalize(bhv) * ((bhmass) / r);
+
+    noncaptured = smoothstep(0.0f, 0.666f, sdSphere(p - bh, bhr));
+
+        // Texture for the accretion disc
+    float dr = length(bhv.xz);
+    float da = atan(bhv.x, bhv.z);
+    vec2 ra = vec2(dr, da * (0.01f + (dr - bhr) * 0.002f) + 2.0f * pi + iTime * 0.005f);
+    ra *= vec2(10.0f, 20.0f);
+
+    vec3 dcol = mix(c2, c1, pow(length(bhv) - bhr, 2.0f)) * max(0.0f, texture(iChannel1, ra * vec2(0.1f, 0.5f)).r + 0.05f) * (4.0f / ((0.001f + (length(bhv) - bhr) * 50.0f)));
+
+    col += max(vec3(0.0f), dcol * smoothstep(0.0f, 1.0f, -sdTorus((p * vec3(1.0f, 25.0f, 1.0f)) - bh, vec2(0.8f, 0.99f))) * noncaptured);
+
+    col += vec3(1.0f, 0.9f, 0.85f) * (1.0f / vec3(dot(bhv, bhv))) * 0.0033f * noncaptured;
+
+  }
+  fragColor = vec4(col, 1.0f);
+}
+
+void main() {
+    // gl_FragCoord.xy is pixel coordinates (1..width, 1..height)
+  mainImage(FragColor, gl_FragCoord.xy);
+}